有办法用脚本关联场景恢复的.qrs文件吗

52042722

有办法用脚本关联场景恢复的.qrs文件吗？ 我不想用工具里面的File-Settings-Recovery来设置。 我尝试过 用 recovery对象，但是没有找到对应方法！ 请高手指教

zte_boy

QTP帮助里面描述的很详细啊
Dim qtApp 'As QuickTest.Application ' Declare the Application object variable
Dim qtTestRecovery 'As QuickTest.Recovery ' Declare a Recovery object variable
Dim intIndex ' Declare an index variable

' Open QuickTest and prepare objects variables
Set qtApp = CreateObject("QuickTest.Application") ' Create the Application object
qtApp.Launch ' Start QuickTest
qtApp.New ' Open a new test
qtApp.Visible = True ' Make the QuickTest application visible
Set qtTestRecovery = qtApp.Test.Settings.Recovery ' Return the Recovery object for the current test

If qtTestRecovery.Count > 0 Then ' If there are any default scenarios specified for the test
    qtTestRecovery.RemoveAll ' Remove them
End If

' Add recovery scenarios
qtTestRecovery.Add "C:\Recovery.qrs", "ErrMessage", 1 ' Add the "ErrMessage" scenario as the first scenario
qtTestRecovery.Add "C:\Recovery.qrs", "AppCrash", 2 ' Add the "AppCrash" scenario as the second scenario
qtTestRecovery.Add "C:\Recovery.qrs", "ObjDisabled", 3 ' Add the "ObjDisabled" scenario as the third scenario

' Enable all scenarios
For intIndex = 1 To qtTestRecovery.Count ' Iterate the scenarios
    qtTestRecovery.Item(intIndex).Enabled = True ' Enable each Recovery Scenario (Note: the 'Item' property is default and can be omitted)
Next

' Enable the recovery mechanism (with default, on errors, setting)
qtTestRecovery.Enabled = True

'Ensure that the recovery mechanism is set to be activated only after errors
qtTestRecovery.SetActivationMode "OnError"
'OnError is the default, the other option is "OnEveryStep".

Set qtApp = Nothing ' Release the Application object
Set qtTestRecovery = Nothing ' Release the Recovery object

52042722

我看过了 但是我看代码中写的要 创建了QTP对象才可以用吧，请版主指点

52042722

哦 知道了 也可以在工具里面创建QTP对象啊  哈哈

zte_boy

当然要创建QTP对象，所有的初始化都应该在QTP启动时加载完成
你可以创建一个vbs文件调用ATO组件来启动QTP并加载你需要的配置

52042722

请问 zte_boy  我试过了 以上方法确实可以，但是有一个问题，就是场景恢复文件一定要启动时载入吗，不能在脚本执行过程中载入吗，如果一定要在启动时载入，我觉得意义不大啊，因为如果是批量执行测试用例，怎么办！

52042722

还有就是 怎么样在已经做好的 用例 中关联上  场景恢复文件。