QTP能否对鼠标悬停信息进行录制？

bowen601

BS结构系统
在数据列表上，鼠标移到一条数据的标题悬停，可以显示该数据的详细信息

问题：QTP可否对该悬停显示的信息进行录制？如何录制？

请高手答疑解惑
谢谢

zte_boy

上午回的，你可以参考下
给你个实例参考
Option Explicit
'定义变量
Dim oWin32    'win32对象
Dim sTitle    '页面标题
Dim arrLinkText    '链接文字数组
Dim sLinkText    '链接文字
Dim sEventName    '操作事件名称
Dim iWaitTime    '两次操作时间间隔
Dim iIdentifyTimeOut    '识别对象超时时间
Dim n    '循环变量

Main

Sub Main
Set oWin32 = CreateObject("wscrīpt.shell")
sTitle = "中国雅虎.*"
arrLinkText = split("站长天下;今日焦点;邮箱;建站;彩票;空间;群组;相册",";",-1,1)    '定义链接文字数组
sEventName = "onmouseover"    '鼠标移到对象上的事件
iWaitTime = 1    '操作等待1秒
iIdentifyTimeOut = 3    '识别对象存在性超时时间设置为3秒

oWin32.Run("http://cn.yahoo.com/")    '打开浏览器，进入中国雅虎首页

For n=0 to ubound(arrLinkText)
  Wait iWaitTime    '操作等待
  sLinkText = arrLinkText(n)    '从链接文字数组中取出链接文字
  moveMouseOnIt    '调用操作时间函数
Next

Browser("title:="&sTitle).Close    '执行完毕关闭浏览器
End Sub

Function moveMouseOnIt()
'检查链接是否存在，存在则触发事件
If Browser("title:="&sTitle).page("title:="&sTitle).link("innertext:="&sLinkText,"index:=0").Exist(iIdentifyTimeOut) Then
  Browser("title:="&sTitle).page("title:="&sTitle).link("innertext:="&sLinkText,"index:=0").FireEvent sEventName   
  moveMouseOnIt = True
  Reporter.ReportEvent micPass,sEventName,"Trigger the event """&sEventName&""" successfully."
Else
  moveMouseOnIt = False
  Reporter.ReportEvent micFail,sEventName,"Fail to trigger the event """&sEventName&""" because of the absence of the link."
End If
End Function

zilter

有些启发 3Q

★斌斌※测试☆

★斌斌※测试☆

内容忒多了！
需要时间！！