一个批处理Test的脚本

danmy

Runlist.txt中写需要运行的Test列表


On Error Resume Next
error.clear
Dim qtApp
Dim qtTest
Dim qtResultsOpt
Dim fso, MyFile,TestName
Const ForReading = 1, ForWriting = 2

Set WshShell = CreateObject("WScript.Shell")
WshShell.Popup "开始批量执行自动化测试脚本！", 3, "AutoTest", 0 + 64

Set qtApp = CreateObject("QuickTest.Application")
qtApp.Launch

qtApp.Visible = False
qtApp.Options.Run.RunMode = "Fast"
qtApp.Options.Run.ViewResults = False

Set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile = fso.OpenTextFile(".\RunList.txt", ForReading, True)
Do While MyFile.AtEndOfStream <> True
        TestName = MyFile.ReadLine

        qtApp.Open TestName, True
        Set qtTest = qtApp.Test
        qtTest.Settings.Run.OnError = "Dialog"
        
        Set qtResultsOpt = CreateObject("QuickTest.RunResultsOptions")
        qtResultsOpt.ResultsLocation = TestName &"\AutoRes"

        qtTest.Run qtResultsOpt, True
        'qtTest.close
Loop

MyFile.Close
qtApp.Quit

MsgBox "自动化测试脚本执行完毕！脚本测试结果存放在各自的AutoRes目录下，请用QTP result工具查看"

Set fso = Nothing
Set qtResultsOpt = Nothing         
Set qtTest = Nothing        
Set qtApp = Nothing
Set WshShell = Nothing

wasd2615

太飘逸了 有没有点注释啊 lz大哥

yluo0898

没有解释怎么看啊？

billygao

RunList.txt 里面需要的是什么list啊？ 大致看明白了，就是在后台把整套测试做一遍，然后把结果分别存到相对应的目录里面。但是唯一不太确定的就是，RunList里面要求什么样的格式啊？是所有脚本文件的名称吗？

danmy

RunList.txt保存Test路径，和这个vbs放在同一目录下

格式就是

C:\autotest\Test1
C:\autotest\Test2
C:\autotest\Test3