如何全自动运行QUICKTEST PREFESSION 脚本

chrisky2

现在已经录制好50个脚本。
想每天凌晨1：00让它们自动跑，跑完后生成report。请问有什么方案解决？
谢谢。

目前考虑了两个方案：
1。将脚本添加到batch runner，通过批处理完成。
2。将脚本添家到QTPlus Automation Generator里，通过批处理完成。

但不知道怎么在批处理中编写-------装载已经存在的文件（batch runner中的.mbt文件或者QTPlus Automation Generator中的.sfl文件），并运行。

请求帮助。

danmy

我之前写过一个这样的脚本，参考下

http://bbs.51testing.com/viewthread.php?tid=85378

rivermen

我也很感兴趣，请共享下

ddq_ddq

能不能把文件也贴出来

zbyufeifei

最简单的是用QC啊，和QTP联在一起不就很容易的搞定啦？！

suifengpiao

xiaonan的方法我试了一下，运行后打开了另外一个文件但是不能运行并且qtp出错，请楼主展示一下代码

[ 本帖最后由 suifengpiao 于 2007-2-27 16:35 编辑 ]

风过无息

楼主，能不能把文件也贴出来，SHOW 一下啊。

chrisky2

方法如下：
建立bat文件，采用QTPlusAutomationGenerator命令。

kissing

banban 是人才。。。。

xiaonan

也可以运用一些自动化脚本,可以到帮助里查看

'************************************************************************************************************************
'描述：
'
'该示例打开测试，配置运行选项和设置，
'运行该测试，然后检查测试运行的结果。
'
'假定：
'QuickTest 中当前未打开没有保存的测试。
'有关详细信息，请参阅 Test.SaveAs 方法的示例。
'打开 QuickTest 时，将加载测试所必需的加载项。
'有关详细信息，请参阅 Test.GetAssociatedAddins 方法的示例。
'************************************************************************************************************************

Dim qtApp ' As QuickTest.Application ' 声明 Application 对象变量
Dim qtTest 'As QuickTest.Test ' 声明 Test 对象变量
Dim qtResultsOpt 'As QuickTest.RunResultsOptions ' 声明 Run Results Options 对象变量

Set qtApp = CreateObject("QuickTest.Application") ' 创建 Application 对象
qtApp.Launch ' 启动 QuickTest
qtApp.Visible = True ' 使 QuickTest 应用程序可见

' 设置 QuickTest 运行选项
qtApp.Options.Run.CaptureForTestResults = "OnError"
qtApp.Options.Run.RunMode = "Fast"
qtApp.Options.Run.ViewResults = False

qtApp.Open "C:\Tests\Test1", True ' 以只读模式打开测试

' 为测试设置运行设置
Set qtTest = qtApp.Test
qtTest.Settings.Run.IterationMode = "rngIterations" ' 仅运行循环 2 到 4
qtTest.Settings.Run.StartIteration = 2
qtTest.Settings.Run.EndIteration = 4
qtTest.Settings.Run.OnError = "NextStep" ' 指示 QuickTest 在发生错误时执行下一步骤

Set qtResultsOpt = CreateObject("QuickTest.RunResultsOptions") ' 创建 Run Results Options 对象
qtResultsOpt.ResultsLocation = "C:\Tests\Test1\Res1" ' 设置结果位置

qtTest.Run qtResultsOpt ' 运行测试

MsgBox qtTest.LastRunResults.Status ' 检查测试运行的结果
qtTest.Close ' 关闭测试

Set qtResultsOpt = Nothing ' 释放 Run Results Options 对象
Set qtTest = Nothing ' 释放 Test 对象
Set qtApp = Nothing ' 释放 Application 对象