51Testing软件测试论坛

标题: 【头脑风暴】如何在脚本运行时，Log中能记录当前进入的函数 [打印本页]
作者: 黑羽祭    时间: 2013-1-24 15:32
标题: 【头脑风暴】如何在脚本运行时，Log中能记录当前进入的函数
本帖最后由 黑羽祭 于 2013-1-24 15:58 编辑

头脑风暴一下，如何在脚本运行时，Log中能记录当前进入的函数
各位都是如何实现的?
如：进入函数A，再进入函数B
就是能很清楚的打印出 [A>>B]这样的一个路径
当脚本出现问题，能很容易定位到是在[A>>B]还是[A>>C]的问题。
作者: 黑羽祭    时间: 2013-1-24 15:33
大家随意发言~
作者: lsekfe    时间: 2013-1-24 15:42
进来支持下。。。不错的话题！
作者: 黑羽祭    时间: 2013-1-25 09:06
厄~肿么没人说话呢~
作者: 赵佳乐SMILE    时间: 2013-1-25 11:42
因为不会啊 不会打log呢
最好是写一个共通 然后每个函数调一下这个共通

共通应该是
你进入一个函数就取得函数名  不知道有没有这个方法
返回一个执行结果
然后拼呗
=====
A OK
B NG
====
A OK
C OK
作者: 黑羽祭    时间: 2013-1-25 16:58
本帖最后由 黑羽祭 于 2013-1-25 17:00 编辑

回复 5# 赵佳乐SMILE


    好吧，那我来抛砖引玉一下~比如：我在外部vbs文件中写入一段脚本，是个log工具的class：
  1. Set Lg   = new LogTools      '实例化 LogTools

  3. Class LogTools
  4.     Dim LogFileName        'log文件名
  5.     Dim LogFilePath           'log文件路径
  6.     Dim isPtLog                 '是否打印日志
  7.     Dim NowFunctionDir    '当前Function的路径
  8.    
  9.     Sub Class_Initialize
  10.         Call NewLogFolder
  11.         Call NewLogFile
  12.         Depth = 0
  13.     End Sub

  15.     Sub Class_Terminate
  16.         
  17.     End Sub
  18.    
  19.     '------------------------------------------------------------------------
  20.     '返值：log文件名
  21.     Property Get getLogFileName()  
  22.         '处理 LogFileName
  23.         If IsEmpty(LogFileName) Then
  24.             LogFileName = "log" & getUniqueNumber & ".txt"
  25.         End If
  26.         
  27.          getLogFileName = LogFileName
  28.     End Property
  29.    
  30.     '------------------------------------------------------------------------
  31.     '返值：log文件路径
  32.     Property Get getLogFilePath()
  33.         '处理 LogFilePath
  34.         If IsEmpty(LogFilePath) Then LogFilePath = Environment("TestDir") & "\LOG\" & getLogFileName
  35.         
  36.         getLogFilePath = LogFilePath
  37.     End Property
  38.    
  39.     '------------------------------------------------------------------------
  40.     '返值：当前Function的路径
  41.     Property Get getNowFunctionDir()
  42.         getNowFunctionDir = NowFunctionDir
  43.     End Property
  44.    
  45.     '------------------------------------------------------------------------------
  46.     '属性：是否打印 log
  47.     Property Let isPrintLog(ByVal oValue)
  48.          isPtLog = oValue
  49.          isPrintLog = isPtLog
  50.     End Property
  51.     Property Get isPrintLog()
  52.         If IsEmpty(isPtLog) Then
  53.             '给默认值
  54.             isPtLog = True
  55.         End If
  56.         isPrintLog = isPtLog
  57.     End Property
  58.    
  59.     '------------------------------------------------------------------------
  60.     '作用：新建Log文件夹
  61.     Sub NewLogFolder()
  62.         Dim FSO , FolderDir
  63.         Set FSO = CreateObject("Scripting.FileSystemObject")
  64.         FolderDir = Environment("TestDir") & "\LOG"
  65.         If Not(FSO.FolderExists(FolderDir)) Then
  66.             FSO.CreateFolder(FolderDir)
  67.         End If
  68.         Set FSO = Nothing
  69.     End Sub
  70.    
  71.     '------------------------------------------------------------------------
  72.     '作用：新建Log文件
  73.     Sub NewLogFile()
  74.         '新建文件
  75.         Dim FSO
  76.         Const ForReading=1,ForWriting=2,ForAppending=8      '参数赋值（1：只读，2：只写，3：追加）
  77.         Set FSO = CreateObject("Scripting.FileSystemObject")    '创建一个文本对象
  78.         Set LOGFILE = FSO.OpenTextFile(getLogFilePath,8,true)
  79.         wait 3
  80.         Set LOGFILE = Nothing
  81.         Set FSO = Nothing
  82.     End Sub

  84.    '------------------------------------------------------------------------
  85.     '作用：重写 Log
  86.     '参数：oWords：需要打印的内容
  87.     Sub Log(oWords)
  88.         '是否打印的判断
  89.         If isPrintLog = False Then Exit Sub
  90.         
  91.         '处理打印内容
  92.         oWords = "[" & now & "] [" & NowFunctionDir & "] " & oWords
  93.         
  94.         'Log 写入QTP
  95.         print oWords
  96.         
  97.         'LOG 写入外部文件
  98.         Dim FSO
  99.         Set FSO = CreateObject("Scripting.FileSystemObject")
  100.         Set ologFile = FSO.OpenTextFile(getLogFilePath, 8, true)
  101.         ologFile.WriteLine (CStr(oWords))
  102.         ologFile.Close
  103.         Set ologFile = Nothing
  104.         Set FSO = Nothing
  105.     End Sub


  108.    '------------------------------------------------------------------------
  109.     '作用：进入 Function 时的标记
  110.     '参数：oFunctionName：Function名
  111.     Sub GoIn(oFunctionName)
  112.         NowFunctionDir = NowFunctionDir & ">>" & oFunctionName
  113.         Log "-----------------进入<" & oFunctionName & ">-----------------"
  114.     End Sub
  115.    
  116.    
  117.     '------------------------------------------------------------------------
  118.     '作用：出 Function 时的标记
  119.     Sub GoOut()
  120.         Dim arrFunDir
  121.         arrFunDir = split(NowFunctionDir , ">>" , -1 , 1)
  122.         Log "-----------------退出<" & arrFunDir(ubound(arrFunDir)) & ">-----------------"
  123.         
  124.         NowFunctionDir = ""
  125.         Dim i
  126.         For i = 1 To ubound(arrFunDir) - 1
  127.             NowFunctionDir = NowFunctionDir & ">>" & arrFunDir(i)
  128.         Next
  129.     End Sub
  130.    
  131.    
  132.     '------------------------------------------------------------------------------
  133.     '作用：得到一个唯一的值
  134.     Function getUniqueNumber()  
  135.         Dim yyyy,mm,dd,ss
  136.         Dim nowtime
  137.         nowDate = date
  138.         nowTimer = cstr(int(timer))
  139.         yyyy = CStr(Year(nowDate))
  140.         mm = CStr(String(2 - Len(Month(nowDate)) , "0") & Month(nowDate))
  141.         dd = CStr(String(2 - Len(Day(nowDate)) , "0") & Day(nowDate))
  142.         ss = CStr(String(5 - Len(nowTimer) , "0") & nowTimer)
  143.         GetUniqueNumber = yyyy & mm & dd & ss
  144.     End Function
  145.    
  146. End Class
复制代码



然后，在Action中随便写一点调用函数的测试脚本：
  1. lg.Log "开始示范"
  2. Call Main


  5. Public Sub Main()
  6.     lg.GoIn "Main"
  7.     '----------------------------------------------------------
  8.     lg.Log "我在Main函数里111"
  9.     Call test1()
  10.     lg.Log "我在Main函数里222"
  11.     lg.isPrintLog = False     '关闭LOG打印
  12.     lg.Log "这个不会出现的"
  13.     '----------------------------------------------------------
  14.     lg.GoOut
  15. End Sub

  17. Function test1()
  18.     lg.GoIn "test1"
  19.     '----------------------------------------------------------
  20.     lg.Log "我在test1函数里111"
  21.     Call test2()
  22.     lg.Log "我在test1函数里222"
  23.     '----------------------------------------------------------
  24.     lg.GoOut
  25. End Function

  27. Function test2()
  28.     lg.GoIn "test2"
  29.     '----------------------------------------------------------
  30.     lg.Log "我在test2函数里"
  31.     '----------------------------------------------------------
  32.     lg.GoOut
  33. End Function
复制代码



运行后，打印的结果是：
[2013/1/25 16:52:55] [] 开始示范
[2013/1/25 16:52:55] [>>Main] -------------------进入<Main>-------------------
[2013/1/25 16:52:55] [>>Main] 我在Main函数里111
[2013/1/25 16:52:55] [>>Main>>test1] -------------------进入<test1>-------------------
[2013/1/25 16:52:55] [>>Main>>test1] 我在test1函数里111
[2013/1/25 16:52:55] [>>Main>>test1>>test2] -------------------进入<test2>-------------------
[2013/1/25 16:52:55] [>>Main>>test1>>test2] 我在test2函数里
[2013/1/25 16:52:55] [>>Main>>test1>>test2] -------------------退出<test2>-------------------
[2013/1/25 16:52:56] [>>Main>>test1] 我在test1函数里222
[2013/1/25 16:52:56] [>>Main>>test1] -------------------退出<test1>-------------------
[2013/1/25 16:52:56] [>>Main] 我在Main函数里222


当然在这个脚本的目录下的LOG文件夹内，也会有个这样内容的文本文件。
但这段脚本有个小毛病，如果我用Exit Function写在中间，就必须在Exit Function前写上一句lg.Log，不然[]中的记录会错位




作者: 赵佳乐SMILE    时间: 2013-1-27 09:51
回复 6# 黑羽祭


    好厉害。
作者: user603    时间: 2013-1-28 17:27
好，学习学习。
作者: yuermoon    时间: 2013-4-19 08:55
不用那么复杂吧。创建一个文本对象，然后在调用函数的初始，用writeline("目前进入**函数")写到日志里面去就可以了啊。
作者: 黑羽祭    时间: 2013-4-19 09:49
回复 9# yuermoon


    终于有人回了。没错，是可以这样。
我这也是个引子，我想能更清晰的记录一下当前位置，如果出现问题，方便查看嘛。
如果遇到：
Call A
Function A()
    Call B
    print "出错"
End Function
Function B()
    print "出错"
End Function
这样的情况，只用进入时打印一下，就不知道那句出错是出错在FunctionA中还是FunctionB中，其实现在又点想法了，自己在优化试试
作者: shingo0109    时间: 2013-4-19 09:50
可以在每个函数里的开头加个“进入xx函数”log语句， 在函数最后再加个“退出xx函数”log语句， 如果函数中间有Exit Function， 那在Exit 之前加个“退出xx函数”的log语句， 只要一个函数有开始和退出Log, 就可以表示执行成功了
作者: 黑羽祭    时间: 2013-4-19 09:55
回复 11# shingo0109


    是啊，我不就是这么做的嘛，只是在这个基础上加了个 路径的保证 和 文件存在否的保证，再加了个能随时打印文件名的Class参数，和一个是否打印LOG的开关量



欢迎光临 51Testing软件测试论坛 (http://bbs.51testing.com/) Powered by Discuz! X3.2