软件测试论坛 › [QuickTest Professional] › 从QC自动启动qtp如何自动加载插件

David_D_Liu 发表于 2007-11-27 20:04:29

从QC自动启动qtp如何自动加载插件

从QC的测试集中自动启动QTP的时候安装的那些插件都是没有被加载的，请问一下如何设置自动启动QTP时QTP插件的加载设置？是在QC下设置还是在QTP下设置，请指教。

hsjzfling 发表于 2007-11-28 12:23:04

'此函数用于加载指定Test所有的插件，若要运行Test可自己加个qtApp.Test.Run
Function Load_Addins(testPath)
      Dim qtApp 'As QuickTest.Application
      Dim blnNeedChangeAddins
      Dim arrTestAddins
      Set qtApp = CreateObject("QuickTest.Application")
      arrTestAddins = qtApp.GetAssociatedAddinsForTest(testPath)
      blnNeedChangeAddins = False
      For Each testAddin In arrTestAddins
            If qtApp.Addins(testAddin).Status <> "Active" Then
                blnNeedChangeAddins = True
                Exit For
            End If
      Next
      If qtApp.Launched And blnNeedChangeAddins Then
             qtApp.Quit
      End If
      If blnNeedChangeAddins Then
            Dim blnActivateOK
            blnActivateOK = qtApp.SetActiveAddins(arrTestAddins, errorDescription)
            If Not blnActivateOK Then
                Call ErrorLog(errorDescription)'这里是调用自己的日志函数，可替换为自己的或注释掉
                  WScript.Quit
            End If
      End If
      If Not qtApp.Launched Then
            qtApp.Launch
      End If
      qtApp.Visible = True
      qtApp.Open testPath
'可在此加入qtApp.Test.Run来运行Test
      Set qtApp = Nothing
End Function

songyq521 发表于 2009-6-12 11:40:01

请问下，这个函数是加在QC里面吗？

hihotb 发表于 2009-6-14 15:39:37

谢谢，学习了

查看完整版本: 从QC自动启动qtp如何自动加载插件