软件测试论坛 › [QuickTest Professional] › qtp与外部xml文件数据的传递

chengyujiao 发表于 2013-7-5 10:58:49

qtp与外部xml文件数据的传递

我新建了一个xml文件，如何用vbs语言实现将case1运行过程中的值传送到case2的调用action中使用？
例如 case1 运行中产生一个系统当前时间值currenttime，如何将这个值写入xml文件，并从case2中读取，应用在case2的action中。
请各位高手帮帮忙

wuxue107 发表于 2013-7-5 22:30:20

下面就是我用的。
Dim objconfig ,v_file
Public Function openconfig(file)
        v_file = file
        Set objconfig = CreateObject("msxml2.domdocument")
        If CreateObject("scripting.filesystemobject").FileExists(v_file) Then
                objconfig.load file
        Else
                objconfig.loadXML "<root><param></param></root>"
        End If
End Function

Public Function getconfig(name)
        Set tmp = objconfig.selectSingleNode("/root/param/"&name)
        If tmp Is Nothing Then
                getconfig = ""
        Else
                getconfig = tmp.text
        End If
End Function

Public Function setconfig(name,value)
        Set tmp = objconfig.selectSingleNode("/root/param/"&name)
        If tmp Is Nothing Then
                Set newelement = objconfig.createElement(name)
                newelement.text = value
                objconfig.selectSingleNode("/root/param").appendChild newelement
        Else
                tmp.text = value
        End If
        objconfig.save v_file
End Function

''########   使用例子##########
openconfig "mm.xml"
setconfig "testname","test01"
MsgBox getconfig("testname")

chengyujiao 发表于 2013-7-8 10:12:30

回复 2# wuxue107


    谢谢你，问题解决了

查看完整版本: qtp与外部xml文件数据的传递